Флаги.

O D I T S Z A P C
*       * * * * * 

Команда:

SCASB

Логика

CMP AL, (ES:DI) ;только устанавливает признаки
                 if DF = 0
                     DI = DI + 1
                 else
                     DI = DI - 1 

Эта команда сравнивает AL с байтом на который указывает ES:DI, и устанавливает признаки в соответствии с результатами сравнения. Сами операнды не изменяются. После сравнения, DI увеличивается на 1, если признак направления сброшен, или уменьшается на 1, если признак направления установлен. Тем самым подготавливается к сравнению следующий байт.

Операнды	Такт байты (слова)	Обращения	Байты	Пример
нет операндов	15	1	1	SCASB
(повтор)	9+15	/rep 1/rep	1	REPNE SCASB

Примечание :
Команда SCASB полезна в тех случаях, когда требуется найти ячейку с заданным байтом. Если Вы хотите сравнить две строки из памяти поэлементно, то используйте команду CMPSB.

Пример
Пусть имеет место следующее определение :

LOST_A    DB   100 dup  (?) 

Тогда следующий пример описывает поиск символа 'A' в блоке памяти длиной 100 байтов, начинающемся с LOST_A:

                  MOV  AX,DS
                  MOV  ES,AX     		;SCASB использует ES:DI,
                                 		;поэтому копируем DS в ES
                  CLD            		;сканировать будем в прямом направлении
                  MOV  AL,'A'    		;ищем "потерянное" 'A'
                  MOV  CX,100    		;сканировать будем 100 байтов
                                 		;(CX используется в REPNE)
                  LEA  DI,LOST_A 		;засылаем стартовый адрес в DI
           REPNE  SCASB          		;ищем 'A'
                  JE   FOUND     		;признак ZF равен 1, если мы нашли 'A'
         NOTFOUND:             		;если мы попали сюда,
                               		;то 'A' не обнаружено
                       
            FOUND:DEC  DI        		;возвращаем указатель DI на первое
                                		;обнаруженное вхождение 'A'

После выхода из цикла REPNE SCASB, ZF=1, если вхождение 'A' было обнаружено, и ZF=0, иначе. В первом случае DI указывает на байт, следующий за байтом, где находится 'A', поэтому мы производим коррекцию указателя DI с помощью DEC DI.